Btukfyl

Dim arr() As String = {"Cake", "Mouse", "Heat", "Tent", "Boots", "Pen", "Stairs", "Cube", "Lion", "Cookies", "Ruler", "Ink"}

Dim timing As Boolean = True

Dim i As Integer = 0

Dim n As Integer = 3000

Private Sub Button1_Click(sender As Object, e As EventArgs)

    Timer1.Start()

    For i = 0 To 11

        While timing = True

            If Timer1.Interval = n Then

                Lbl_Word.Text = arr(i)

                timing = False

            End If

        End While

        timing = True

    Next

    Timer1.Stop()

End Sub

The text of the label isn't changing and i'm not sure what I've done wrong. Please help.

If you are using a forms timer then the code to update the label must be in the .Tick event. The code below uses a static variable in the event handler to track which string to show.

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

    Timer1.Interval = 3000

    If Not Timer1.Enabled Then 'already running?

        Timer1.Start() 'no

    End If

End Sub



Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick

    Dim arr() As String = {"Cake", "Mouse", "Heat", "Tent", "Boots", "Pen", "Stairs", "Cube", "Lion", "Cookies", "Ruler", "Ink"}

    'Dim arr() As String = {"Cake", "Mouse", "Heat"} 'to test

    Static idx As Integer = 0 'which index in arr

    If idx < arr.Length Then 'more to show?

        'yes

        Lbl_Word.Text = arr(idx)

        idx += 1

    Else

        'no

        Timer1.Stop()

        idx = 0

    End If

End Sub

An alternative approach without using a timer.

Private TmrTask As task

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

    If TmrTask Is Nothing OrElse TmrTask.IsCompleted Then

        TmrTask = Task.Run(Sub() MyTimerTask())

    End If

End Sub



Private Sub MyTimerTask()

    Dim arr() As String = {"Cake", "Mouse", "Heat", "Tent", "Boots", "Pen", "Stairs", "Cube", "Lion", "Cookies", "Ruler", "Ink"}

    'Dim arr() As String = {"Cake", "Mouse", "Heat"} 'to test

    For Each s As String In arr

        Me.BeginInvoke(Sub()

                           Lbl_Word.Text = s

                       End Sub)

        Threading.Thread.Sleep(3000)

    Next

End Sub

you have to put the code inside the Timer events. not in the Button Click event.
and in the Button click event just enable the timer.

-Add a timer

• Make the interval 3000


• On the timer event change the label background color to the color you want you can use from RGB or use random numbers