Btukfyl

I'm trying to write a custom rule to compile C++ code using the cc_common API. Here's my current attempt at an implementation:

load("@bazel_tools//tools/cpp:toolchain_utils.bzl", "find_cpp_toolchain")   

load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "C_COMPILE_ACTION_NAME") 



def _impl(ctx):

    cc_toolchain = find_cpp_toolchain(ctx)

    feature_configuration = cc_common.configure_features(

        cc_toolchain = cc_toolchain,

        unsupported_features = ctx.disabled_features,

    )

    compiler = cc_common.get_tool_for_action(

        feature_configuration=feature_configuration,

        action_name=C_COMPILE_ACTION_NAME

    )

    compile_variables = cc_common.create_compile_variables(

        feature_configuration = feature_configuration,

        cc_toolchain = cc_toolchain,

    )

    compiler_options = cc_common.get_memory_inefficient_command_line(

        feature_configuration = feature_configuration,

        action_name = C_COMPILE_ACTION_NAME,

        variables = compile_variables,

    )



    outfile = ctx.actions.declare_file("test.o")

    args = ctx.actions.args()

    args.add_all(compiler_options)

    ctx.actions.run(

        outputs = [outfile],

        inputs = ctx.files.srcs,

        executable = compiler,

        arguments = [args],

    )



    return [DefaultInfo(files = depset([outfile]))]

However, this fails with the error "execvp(external/local_config_cc/wrapped_clang, ...)": No such file or directory. I assume this is because get_tool_for_action returns a string representing a path, not a File object, so Bazel doesn't add wrapped_clang to the sandbox. Executing the rule with sandboxing disabled seems to confirm this, as it completes successfully.

Is there a way to implement this custom rule without disabling the sandbox?

If you use ctx.actions.run_shell you can add the files associated with the toolchain to the input (ctx.attr._cc_toolchain.files). Also, you'll want to add the compiler environment variables. E.g.

srcs = depset(ctx.files.srcs)

tools = ctx.attr._cc_toolchain.files

...

compiler_env = cc_common.get_environment_variables(

   feature_configuration = feature_configuration,

   action_name = C_COMPILE_ACTION_NAME,

   variables = compiler_variables,

)

...

args = ctx.actions.args()

args.add_all(compiler_options)

ctx.actions.run_shell(

    outputs = [outfile],

    inputs = depset(transitive = [srcs, tools]), # Merge src and tools depsets

    command = "{compiler} $*".format(compiler = compiler),

    arguments = [args],

    env = compiler_env,

)

Bazel doesn't add files as action inputs automatically, you have to do it explicitly, as you did in your second approach (ctx.attr._cc_toolchain.files). With that, ctx.actions.run should work just fine.